// thread for parsing Scratch data 
// sending data from Scratch as OSC
// configuring the bridge from Scratch

class SimpleThread extends Thread {
  
    // from: http://wiki.processing.org/w/Threading
  
    boolean running;           // Is the thread running?  Yes or no?
    int wait;                  // How many milliseconds should we wait in between executions?
    String id;                 // Thread name
    int count;                 // counter
   
    // Constructor, create the thread
    // It is not running by default
    SimpleThread (int w, String s) {
      wait = w;
      running = false;
      id = s;
      count = 0;
    }

    // Overriding "start()"
    void start () {
      // Set running equal to true
      running = true;
      // Print messages
      println("Starting thread (will execute every " + wait + " milliseconds.)"); 
      // Do whatever start does in Thread, don't forget this!
      super.start();
    }
    
     // We must implement run, this gets triggered by start()
    void run () {
      while (running) {  
        parseScratchData();
        
        try { sleep((long)(wait));
        } 
        catch (Exception e) {
        }
      }
    }
    
    void parseScratchData()
    {      
        if (scratchClient.available()>0) {
          int expectedStringLength;
          
          String receivedString = scratchClient.readString();      
          
          // we split (Java split, Processing split doesn't work with regex) on first 3 null bytes. 
          // 4th byte is the length of the expected string    
          String[] m = receivedString.split("\\x00\\x00\\x00");
          
          if(m!=null)
          { for (int i = 1; i < m.length; i++) {
                           
              expectedStringLength = int(m[i].charAt(0));  
              
              // cut the first character
              m[i] = m[i].substring(1, m[i].length()); // remove 1st character
      
              if((m[i].length())==expectedStringLength)
              { String[][] incomingMatch = matchAll(m[i], "\"[^\"]+\"|-?[0-9]+[.][0-9]+|-?[0-9]+");
                           
                if (incomingMatch != null) 
                { //println("after match: "+m[i]);
                  String[] checkIsSensor = match(m[i],"sensor");
                  
                  if(checkIsSensor != null) parseSensorData(incomingMatch);
                  else                      parseBroadcastData(incomingMatch);             
                }
              }
            }
          }
           
          scratchClient.clear();  
        }  
    }
    
    void parseSensorData(String[][] incomingMatch)
    { //println("sensor");
      String label; 
    
      for(int i=0;i<incomingMatch.length;i+=2) {
                          
        // remove double quotes from label
        label = (incomingMatch[i][0]).replace("\"","");
        
        // let only variable names starting with / pass through. 
        if(label.charAt(0) == '/')
        { // extra check if its complete
          if((i+1)<incomingMatch.length) sendOSCMessage(label, incomingMatch[i+1][0]);
          else
          { monitorList2.add((String) "error missing value for label: "+label);  
          } 
        }
        else
        { if(isAllData)
          { // send all variables as OSC data
            if(label.charAt(0) != '/') label = "/"+label; 
            
            if((i+1)<incomingMatch.length) sendOSCMessage(label, incomingMatch[i+1][0]);
            else
            { monitorList2.add((String) "error missing value for label: "+label);  
            }    
          }                 
        }
      }
    }
    
    void parseBroadcastData(String[][] incomingMatch)
    { //println("broadcast");
      String label; 
      
      for(int i=0;i<incomingMatch.length;i++)   
      { // remove double quotes
        label = (incomingMatch[i][0]).replace("\"","");
        //println("broadcast "+label);
        
        // configure this client by broadcast messages
                 
        if(match(label, "^listenPort(=| =)")!=null) 
        { String[] s = split(label, '=');
          // call textInput function to add the port to the list
          textInput(s[1]);      
          monitorList2.add((String) "- Added OSC listening port "+s[1]+" with a broadcast message from Scratch");                  
        }
        
        if(match(label, "^sendPort(=| =)")!=null) 
        { String[] s = split(label, '=');
          // call textInput function to add the port to the list
          textInput3(s[1]);
          monitorList2.add((String) "- Set OSC sending port"+s[1]+" with a broadcast message from Scratch");                  
        }
        
        if(match(label, "^sendIp(=| =)")!=null) 
        { String[] s = split(label, '=');
          // call textInput function to add the port to the list
          textInput2(s[1]);
          monitorList2.add((String) "- Set OSC sending IP address"+s[1]+" with a broadcast message from Scratch");                  
        }
        
        if(match(label, "^setPrefix(=| =)")!=null) 
        { String[] s = split(label, '=');
          // call textInput function to add the port to the list
          textInput4(s[1]);
          monitorList2.add((String) "- Set OSC prefix "+s[1]+" with a broadcast message from Scratch");                  
        }
    
        if(match(label, "^listenAddress(=| =)")!=null)
        { String[] s = split(label, '=');
          s[1]=trim(s[1]);
          if(s[1].charAt(0) != '/') s[1]="/"+s[1];
                           
          addOSCaddressByScratch(s[1]);                                                  
          monitorList2.add((String) "- Added an \"send OSC address to Scratch\" address: "+s[1]+" with a broadcast message from Scratch"); 
        }
        
        if(label.charAt(0) == '/')
        { sendOSCMessage(label, "");
        }
        else
        { if(isAllData)
          { if(label.charAt(0) != '/') label = "/"+label; 
            sendOSCMessage(label, "");
          }
        }                
      }  
    }
    
    // Our method that quits the thread
    void quit() {
      System.out.println("Quitting."); 
      running = false;  // Setting running to false ends the loop in run()
      // IUn case the thread is waiting. . .
      interrupt();
    }
}  

void sendOSCMessage(String label, String value)
{
  OscMessage oscMessage = new OscMessage(addressPrefix+label);
  
  // add a value if there is one (broadcasts don't have a value)
  if(value != "") 
  { // leave it a string or convert it to a float...
    String[] m = match(value, "[^0-9\\.]+");
    if(m!=null) 
    { 
      // convert true en false also to a float
      String [] matchFalse = match(value, "^\"false\"$");
      String [] matchTrue  = match(value, "^\"true\"$");
      if(matchFalse!=null) 
      { oscMessage.add(float(0)); 
        value = "0.0"; // for monitor
      }
      else if(matchTrue!=null)
      { oscMessage.add(float(1));
        value = "1.0"; // for monitor
      }
      else
      {  // value is a string
         oscMessage.add(value); 
      }      
    }
    else
    { // value is a number
      oscMessage.add(float(value));
    }
  }
            
  OscP5.flush(oscMessage, transmitaddress);  
                     
  monitorList2.add((String) addressPrefix+label+" "+value);  
}