/*   

  Program to draw wordnet DOT format graph saved as XML
  from pygraph.
  r@roberttwomey.com
  
  Adapted from:
  
  Graphtoy by Sean McCullough 
  http://www.cricketschirping.com
  26. Feb 2007
*/

import traer.physics.*;
import traer.animation.*;

Graph g;
ParticleSystem physics;
Smoother3D centroid;

boolean paused;

XMLElement xml;

PFont font;
float t_step;
ArrayList deleted_edges;
  
void setup()
{

  size( 800, 800 );
  smooth();
  fill( 0 );
  frameRate( 24 );
  ellipseMode( CENTER );
  font = loadFont("CourierNew36.vlw"); 
  t_step=0.01;
  
  physics = new ParticleSystem( 0, 0.07 );
  centroid = new Smoother3D( 0.8 );
  centroid.setValue( 0, 0, 1.0 );

  deleted_edges = new ArrayList();
  g = new Graph(physics);

  Node anchor = g.newNode("Art");
  anchor.setLabel("Art");
  anchor.getParticle().makeFixed();

  g.setSelectedNode(anchor);

  loadXMLFile(anchor, "script res.xml");

//  loadXMLFile(anchor, "visual memory reference.xml");
}

void loadXMLFile(Node root, String filename) {
  Node n = null;
  Edge e = null;
  
  xml = new XMLElement(this, filename);
  int numNodes = xml.getChildCount();
  
  for (int i=0; i<numNodes; i++) {
    XMLElement element = xml.getChild(i);
    String name = element.getName();
    if(name.equals("node")) {
      String label = element.getStringAttribute("id");
      println(label);
      n = g.newNode(root, label);
      n.setLabel(label);
      n.getParticle().moveTo(root.getParticle().position().x()+(0.01-(float)Math.random()*0.05), root.getParticle().position().y()+(0.01-(float)Math.random()*0.05), 0.0);       
      //e = g.newEdge(n, root, 1.0, 1.0, 50);
      //e.setLabel(str(0.0));  
  }
    if(name.equals("edge")) {
      String from = element.getStringAttribute("from");
      String to = element.getStringAttribute("to");
      Float weight = element.getFloatAttribute("wt");
      //println("from "+from);
      //println(name);
      weight/=10.0;
      if(weight >= 0.3) {
        e = g.newEdge(g.getNode(from), g.getNode(to), 1.0, 0.9, 300.0-300.0*abs(weight));
        //makeAttraction(g.getNode(from).getParticle(), g.getNode(to).getParticle(), -0.5, 100);
        println(weight);
        e.setLabel(str(weight));
      }
    }
  }
}

void reThreshold(float wt) {
  for (int i=0; i<g.edges.size(); i++) {
      Edge e = (Edge)g.edges.get(i);
  }

}

void keyPressed() {
  if(key==' ')
    paused = (paused == false);
  if((key=='=') || (key=='+')) t_step+=0.001;
  if(key=='-') t_step-=0.001;
  
}

void draw()
{
  if(!paused) physics.advanceTime( t_step );

  updateCentroid();
  centroid.tick();

  background( 255 );
  textFont(font, 16);
  text(t_step, 10, 10);
  
  translate( width/2 , height/2 );
  scale( min(centroid.z(),1.0) );
  translate( -centroid.x(), -centroid.y() );
  g.draw();

}

int mx() {
  return (int)((mouseX-width/2)/min(centroid.z(),1.0) + centroid.x());
}

int my() {
  return (int)((mouseY-height/2)/min(centroid.z(),1.0) + centroid.y());
}

void mousePressed() {  
    ArrayList nodes = g.getNodes();
    for(int i=0; i<nodes.size(); i++) {
      Node n = (Node)nodes.get(i);
      if (n.containsPoint(mx(), my())) {
        g.setSelectedNode(n);
        g.setDragNode(n);
        return;
      }
    }
}

void mouseMoved() {
  if (g.getDragNode() == null) {
    g.setHoverNode(null);
    for(int i=0; i<g.getNodes().size(); i++) {
      Node n = (Node)g.getNodes().get(i);
      if (n.containsPoint(mx(), my())) {
        g.setHoverNode(n);
      }
    }
  }
}

void mouseReleased() {
  g.setDragNode(null);
}


void mouseDragged() {
  if (g.getDragNode() != null) {
    g.getDragNode().setPosition(mx(), my(), 0.0);
  } 
  else {
    //transX += mouseX-pmouseX;
    //transY += mouseY-pmouseY;
  }
}


void updateCentroid()
{
  float 
  xMax = Float.NEGATIVE_INFINITY, 
  xMin = Float.POSITIVE_INFINITY, 
  yMin = Float.POSITIVE_INFINITY, 
  yMax = Float.NEGATIVE_INFINITY;

  for ( int i = 0; i < physics.numberOfParticles(); ++i )
  {
    Particle p = physics.getParticle( i );
    xMax = max( xMax, p.position().x() );
    xMin = min( xMin, p.position().x() );
    yMin = min( yMin, p.position().y() );
    yMax = max( yMax, p.position().y() );
  }
  
  if (physics.numberOfParticles() == 0) 
    return;
    
  float deltaX = xMax-xMin;
  float deltaY = yMax-yMin;
  if ( deltaY > deltaX )
    centroid.setTarget( xMin + 0.5*deltaX, yMin +0.5*deltaY, height/(deltaY+50) );
  else
    centroid.setTarget( xMin + 0.5*deltaX, yMin +0.5*deltaY, width/(deltaX+50) );
}